デスクトップアイコンを右ではなく左側に配置する

自動的にエイリアスまたはアイコンを作成してアップルデスクトップの左側に表示する方法デフォルトではそれらは右に行きます。

10
ru de
これは私が理解できないmacOSの解決策の1つです。なぜAppleはユーザーに右側のアイコンを強制するのですか?あなたはそれらを左にドラッグすることができますが、それはポイントではありません。名前で並べ替えると、すべてが右側に戻ります。 Finderで Desktop ディレクトリを開いても、アイコンは左に揃えられます。それは矛盾しています。私のシステム言語は、アラビア語やヘブライ語ではなく、左から右へのスクリプトに設定されています。これは、有名なAppleユーザーエクスペリエンスですか?
追加された 著者 Randy Stegbauer,
おそらくAppleScriptを使う必要があるでしょう
追加された 著者 0942v8653,

4 答え

アイコンを自動的に左に移動させる(および選択した基準に従って配置されたままにする)方法はありません。

回避策として、Finderの[表示オプション]を変更して、項目をどの基準でも並べずにアイコンを左側に手動で配置することができます。

  • Click on an empty space on the desktop.
  • Press Cmd+J or use the mouse to go to the Finder's View > Show View Options menu.
  • In the Sort by: dropdown in the dialog, choose either None or Snap to Grid.
  • You'll be able to drop files anywhere on your desktop and they'll stay there.

詳しくは、 Macの基本:ウィンドウを変更するをご覧ください。

Macの使い方の詳細については、 Macの基本ページもご覧ください。</強い>

7
追加された
ありがとう。自動部分を見逃して、答えを訂正しました。
追加された 著者 Sam Weaver,
Qは、Finder Viewメニューの自動Clean Up ByとSort Byの選択について質問しています。どうして右に並べるだけなの?
追加された 著者 Zo219,

これは最善の解決策ではありませんが、他に何もしなければうまくいくことがあります...

  1. Create an Automator Folder Action associated with the Desktop.
  2. Add the item: "run applescript"
  3. Paste the following code in the applescript text box:

    -- https://gist.github.com/mrienstra/8330528
    -- Based on http://www.tuaw.com/2012/12/24/applescript-desktop-icon-race/
    -- Inspired by http://namesakecomic.com/comic/happy-new-year-from-namesake/#comment-1182035013
    
    -- Rearranges Desktop icons to flow from left to right, top to bottom.
    
    -- To have this run automatically every time files are added or removed from the Desktop, set this script to run as a Desktop "Folder Action". (See https://developer.apple.com/library/mac/documentation/applescript/conceptual/applescriptlangguide/reference/ASLR_folder_actions.html )
    
    -- This is currently a rough proof-of-concept. It has only been tested with OS X 10.8.5 (Mountain Lion).
    
    -- Current known limitations: Does not work with "Label position" set to "Right" (specifically, icons will overlap).
    
    
    
    -- Adjust these for different spacing
    property theSpacingFactor : 1.0
    property theGutterXFactor : 0.57
    property theGutterYFactor : 0.57
    
    
    
    on rearrangeDesktopIcons()
        tell application "Finder"
            tell icon view options of window of desktop
                set theArrangement to arrangement
                set theArrangementString to theArrangement as string
                if {"not arranged", "«constant ****narr»", "snap to grid", "«constant ****grda»"} does not contain theArrangementString then
                    display alert "\"Rearrange Desktop Icons\" AppleScript says:" message "Cannot rearrange Desktop items, please change Desktop \"Sort by\" to \"None\" or \"Snap to Grid\"." giving up after 10
                    return
                end if
                set theIconSize to icon size
                set theLabelSize to text size
            end tell
    
            set theDesktopBounds to bounds of window of desktop
            set theDesktopWidth to item 3 of theDesktopBounds
            set theDesktopHeight to item 4 of theDesktopBounds
    
            -- Retrieve a list of items on the desktop
            set theDesktopItems to every item of desktop
            set theContestantOffset to theIconSize/2
    
            set theSpacing to (theIconSize + theLabelSize + theContestantOffset) * theSpacingFactor
            set theGuttersX to theSpacing * theGutterXFactor
            set theGuttersY to theSpacing * theGutterYFactor
            set theMaxColumns to ((theDesktopWidth - theGuttersX * 2)/theSpacing) as integer
            set theMaxRows to ((theDesktopHeight - theGuttersY * 2)/theSpacing) as integer
            set theMaxLocations to theMaxRows * theMaxColumns
    
            set y to 1
            repeat with a from 1 to length of theDesktopItems
                set x to a mod theMaxColumns
                if x is 0 then
                    set x to theMaxColumns
                end if
    
                if a is greater than theMaxLocations then
                    set desktop position of item a of theDesktopItems to {theGuttersX, theGuttersY}
                else
                    set desktop position of item a of theDesktopItems to {theGuttersX + (x - 1) * theSpacing, theGuttersY + (y - 1) * theSpacing}
                end if
    
                if a mod theMaxColumns is 0 then
                    set y to y + 1
                end if
            end repeat
        end tell
    end rearrangeDesktopIcons
    
    
    
    on adding folder items to alias after receiving listOfAlias
        rearrangeDesktopIcons()
    end adding folder items to
    
    on removing folder items from alias after losing listOfAliasOrText
        rearrangeDesktopIcons()
    end removing folder items from
    
    rearrangeDesktopIcons()
    

したがって、ファイルがデスクトップに追加されるたびに、すべてのファイルがアルファベット順に並べ替えられます。

2
追加された

右側からすべてのフォルダをハイライトし、それらをすべてつかんで左側に貼り付けました。

2
追加された

すべてのフォルダを好きな順序で整理します。それからビューの下で「クリーンアップ」を押してください。これですべてがうまく揃います。それからあなたは単にすべてのフォルダーをハイライトして、あなたがそれらを望むところに正確に置くことができます。 Macでは、左側にフォルダを整理するのではなく、右側に整理していますが、いくつかの簡単な手順で、すべてを左側に整理することができます。

0
追加された
これは 'ウィンドウ'ではなく 'ビュー'と表示されるはずです。
追加された 著者 rouble,
答えの下に直接テキストを編集できる編集リンクがあります:-)
追加された 著者 Andrew Dunaway,