2つの指定された日付の間の年をすべて取得

私が2年間持っているならば。

YEAR(@STARTDATE) -- 2011
YEAR(@ENDDATE)   -- 2015

@STARTDATE@ENDDATE を含めて、提供された2つの期間のすべての年を含む #YEARRANGE という一時テーブルを作成するにはどうすればよいですか。言い換えれば、それはそのように見えるでしょう:

#YEARRANGE
==========
- 2011
- 2012
- 2013
- 2014
- 2015
3
追加された 著者 Evaldas Buinauskas,

7 答え

あなたはこのように試すことができます:

DECLARE 
      @start DATE = '20120201'
    , @end DATE = '20150405'

;WITH cte AS 
(
    SELECT YEAR(@start) AS [Year]
    UNION ALL
    SELECT yl.[Year]+ 1 as [Year]
    FROM cte  yl
    WHERE yl.[year] + 1 <= Year(@end)
)
SELECT CONVERT(CHAR(4), [Year], 120) 
FROM cte
0
追加された

これは、集計テーブルを使用した別の解決策です。

DECLARE @startDate DATE = '20110101'
DECLARE @endDate DATE = '20150101'

;WITH E1(N) AS(
    SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL 
    SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1
)
,E2(N) AS(SELECT 1 FROM E1 a, E1 b)
,E4(N) AS(SELECT 1 FROM E2 a, E2 b)
,Tally(N) AS(
    SELECT TOP(DATEDIFF(YEAR, @startDate, @endDate) + 1) 
        ROW_NUMBER() OVER(ORDER BY (SELECT NULL))
    FROM E4
)
SELECT
    YEAR(@startDate) + (N-1)
FROM Tally
WHERE
    YEAR(@startDate) + (N-1) <= YEAR(@endDate)
0
追加された

これを再帰的なcteで実行してから、 select into ステートメントを使用して直接一時テーブルを作成します。

DECLARE @sd INT = 2011, @ed INT = 2015

;WITH cte AS(SELECT @sd AS y
             UNION ALL
             SELECT y + 1 FROM cte WHERE y < @ed)
SELECT * INTO #YEARRANGE FROM cte
0
追加された
DECLARE @STARTDATE DATE, @ENDDATE DATE

SET @STARTDATE = '2011-01-10'
SET @ENDDATE = '2015-06-16'

CREATE TABLE #YEARRANGE([YEAR] INT)

;WITH C AS (
        SELECT  DATEPART(YEAR, @STARTDATE) AS yr
        UNION ALL
        SELECT yr + 1
        FROM C
        WHERE yr < DATEPART(YEAR, @ENDDATE)
        )
INSERT INTO #YEARRANGE
SELECT yr
FROM C
ORDER BY yr

SELECT * FROM #YEARRANGE

出力

YEAR
------------
2011
2012
2013
2014
2015
0
追加された
DECLARE @STARTDATE INT  = 2011

DECLARE @ENDDATE INT = 2015

CREATE TABLE #YEARRANGE([YEAR] INT)

WHILE @STARTDATE <= @ENDDATE
BEGIN
    INSERT INTO #YEARRANGE
    VALUES(@STARTDATE)

    SET @STARTDATE = @STARTDATE + 1
END


SELECT * FROM #YEARRANGE

DROP TABLE #YEARRANGE
0
追加された
CREATE TABLE #YEARRANGE
(
    Years INT
)

DECLARE @STARTDATE DATE,
        @ENDDATE DATE;
SET @STARTDATE = '20110101';
SET @ENDDATE = '20150101';

WITH GetYears 
AS
(
    SELECT YEAR(@STARTDATE) AS Years
    UNION ALL
    SELECT yl.Years+ 1 as Years
    FROM GetYears yl
    WHERE yl.Years + 1 <= YEAR(@ENDDATE)
)
INSERT INTO #YEARRANGE
SELECT Years FROM GetYears ORDER BY Years;

SELECT * FROM #YEARRANGE

DROP TABLE #YEARRANGE

出力:

year
2011
2012
2013
2014
2015
0
追加された

Welp、誰かがこの変化に私を打ち負かしたかもしれません。

Declare @StartYear int = 2011
    , @EndYear int = 2015
Declare @YearDiff int = @EndYear - @StartYear 
    , @i int =0 --Counter

if OBJECT_ID('tempdb..#YEARRANGE') is not null
    drop table #YEARRANGE;
Create Table #YEARRANGE (YearRange int)

-- I hate loops in SQL.
while @i <= @YearDiff
begin
    INSERT INTO #YEARRANGE
    select @i + @StartYear
    set @i +=1;
end

/*  Tada    */
Select * 
from #YEARRANGE
0
追加された