テキストファイルを読み込んでPrologのファイルに出力するにはどうしたらいいですか?

私はテキストファイルを持っていて、それを読み込んでスクリーンに印刷し、それらを新しい出力ファイルに書きたいと思っています。私がこれまでにしてきたことは、

main :-
    open('text.txt', read, ID),  % open a stream
    repeat,             % try again forever
    read(ID, X),        % read from the stream
    write(X), nl,       % write to current output stream
    X == end_of_file,   % fail (backtrack) if not end of 
    !,
    close(ID).

しかし、私は、

ERROR: text.txt:1:0: Syntax error: Operator expected

私は何をすべきか?

1

3 答え

read/2 reads valid Prolog text. The message suggests, that in line 1 of text.txt you have some invalid Prolog text. Maybe a couple of words separated by spaces.

通常のテキストを読む場合は、 get_char/2 を使用して非常に低レベルにするか、文法を使用してより高いレベルで行うことができます。 SWI-Prologはそのために library(pio)を持っています。

ここで、Prologプログラマは grep -q と同等です。

?- phrase_from_file((...,"root",...),'/etc/passwd').
true ;
true ;
true ;
false.

実際、それはむしろ grep -c です。

あなたは次の定義をロードする必要があります:

... --> [] | [_], ... .
2
追加された

再利用可能なスニペットが必要な場合:

%%  file_atoms(File, Atom) is nondet.
%
%   read each line as atom on backtrack
%
file_atoms(File, Atom) :-
    open(File, read, Stream),
    repeat,
    read_line_to_codes(Stream, Codes),
    (   Codes \= end_of_file
    ->  atom_codes(Atom, Codes)
    ;   close(Stream), !, fail
    ).

これは、SWI-Prolog組み込み関数であるread_line_to_codesを呼び出します。

1
追加された
is_eof(FlHndl, CharCode, CurrentLine, FileAkku, FileContent) :-
        CharCode == -1,
        append(FileAkku, [CurrentLine], FileContent),
        close(FlHndl), !.

is_newline(FlHndl, CharCode, CurrentLine, FileAkku, FileContent) :-
        CharCode == 10,
        append(FileAkku, [CurrentLine], NextFileAkku),
        read_loop(FlHndl, '', NextFileAkku, FileContent).

append_char(FlHndl, CharCode, CurrentLine, FileAkku, FileContent) :-
        char_code(Char, CharCode),
        atom_concat(CurrentLine, Char, NextCurrentLine),
         read_loop(FlHndl, NextCurrentLine, FileAkku, FileContent).

read_file(FileName, FileContent) :-
        open(FileName, read, FlHndl),
        read_loop(FlHndl, '', [], FileContent), !.

read_loop(FlHndl, CurrentLine, FileAkku, FileContent) :-
        get_code(FlHndl, CharCode),
        ( is_eof(FlHndl, CharCode, CurrentLine, FileAkku, FileContent)
        ; is_newline(FlHndl, CharCode, CurrentLine, FileAkku, FileContent)
        ; append_char(FlHndl, CharCode, CurrentLine, FileAkku, FileContent)).

main(InputFile, OutputFile) :-
    open(OutputFile, write, OS),
    (   read_file(InputFile,InputLines),
        member(Line, InputLines),
        write(Line), nl,
        write(OS,Line),nl(OS),
        false
        ;
        close(OS)
    ).

So, you can use it like main('text.txt', 'output.txt').

0
追加された