Arduino付き2ビット加算器

ピンのラベルは、 A1Pin 、 A0Pin などです。変数名も同じ規則に従います。 a1Value 、 a0Value </これは if 文を理解しやすくします。

それなら、 if ステートメントについて体系的になる必要があります。 4つの入力では、16通りの組み合わせがあり、それぞれに if ステートメントが必要です。また、すべての if ステートメントで every の入力値を確認する必要があります。

最初の2つの if ステートメントは

if (a1Value == LOW && a0Value == LOW && b1Value == LOW && b0Value == LOW)
{
    digitalWrite(LED0Pin,LOW);  //0 + 0 = 0
    digitalWrite(LED1Pin,LOW);
    digitalWrite(LED2Pin,LOW);
}
else if a1Value == LOW && a0Value == LOW && b1Value == LOW && b0Value == HIGH) 
{
    digitalWrite(LED0Pin,HIGH); //0 + 1 = 1
    digitalWrite(LED1Pin,LOW);
    digitalWrite(LED2Pin,LOW);
}

そして最後の if ステートメントは

else if (a1Value == HIGH && a0Value == HIGH && b1Value == HIGH && b0Value == HIGH)
{
    digitalWrite(LED0Pin,LOW);  //3 + 3 = 6
    digitalWrite(LED1Pin,HIGH);
    digitalWrite(LED2Pin,HIGH);
}

あと13行あります。

もちろん、これを実行する方法は他にもありますが、私はあなたが始めたことを終わらせるのを手伝うだけでよいと思いました。

コードが機能したら、コードレビューに投稿して、最適化方法に関するさまざまな提案を得ることができます。

それはむしろあなたが全加算器をシミュレートするのか、それをエミュレートするのかを任されているかどうかによって異なります。あなたがそれをエミュレートしているならば、あなたはピンが（少なくともほとんどの変種のために）AVRポートに割り当てられているという事実を使うことができます。

void loop() {
    int a = (PORTB >> 3) & 3;//take the two 'A' bits from the input port and make a number between 0 and 3
    int b = (PORTB >> 1) & 3;//likewise for 'B'
    PORTD = ( a + b ) << 4;  //add them together and shift to light the LEDs
}

7482を持っていなくて、それをエミュレートしたいのであれば、これが私のやり方です。

ロジックを組み合わせて全加算器を作成する方法を実証することを目的としている場合は、半加算器ロジック sum = a xまたはb と carry = a and b を使用して作成します全加算器ロジック sum =（a xまたはb）xまたはc carry =（aとb）または（cと（a xor b））。

void loop() {
   //input a as two separate bits
    bool a0 = digitalRead(A0Pin);
    bool a1 = digitalRead(A1Pin);

   //input b as two separate bits
    bool b0 = digitalRead(B0Pin);
    bool b1 = digitalRead(B1Pin);

   //half adder for digit 0 of output sum and carry
    bool s0 = a0 ^ b0;
    bool c0 = a0 & b0;

   //full adder for digit 1 of output sum and carry
    bool s1 = (a1 ^ b1) ^ c0;
    bool c1 = (a1 & b1) | (c0 & (a1 ^ b1));

    digitalWrite(LED0Pin, s0);
    digitalWrite(LED1Pin, s1);
    digitalWrite(LED2Pin, c1);//digit2 of output will be carry from digit 1
}

ここでの違いは、動作していることを示していることと、真理値表を一連のifステートメントに変換するのではなく、加算器が何のためにあるのかを理解したことをインストラクターに伝えることです。あなたは2ビット加算器のためにそれを回避するかもしれません、しかし、あなたは手作業で例えば8ビット加算器のすべての可能な入力と出力を書き出したくありません。

Yunnosch氏のコメントに続いて、これは彼があなたが追加の価値を事前に計算して、それからコードを大いに単純化するLEDにそれを表示することができるということであるという意味です 以下のコードはうまくいくはずです - あるいは少なくともガイドラインとして役立ちます 私はあなたが論理を理解するための例でコメントしました、それが助けを願っています

注：私はArduinoの前にいないので、このコードはテストされていません - しかしそれはコンパイルします

int A0Pin = 12;
int A1Pin = 11;
int B0Pin = 10;
int B1Pin = 9;

int LED0Pin = 6;
int LED1Pin = 5;
int LED2Pin = 4;

void setup()
{
  pinMode(A0Pin, INPUT);
  pinMode(A1Pin, INPUT);
  pinMode(B0Pin, INPUT);
  pinMode(B1Pin, INPUT);

  pinMode(LED0Pin, OUTPUT);
  pinMode(LED1Pin, OUTPUT);
  pinMode(LED2Pin, OUTPUT);
}

void loop()
{
  int b1Value = digitalRead(A0Pin);
  int b2Value = digitalRead(A1Pin);
  int b3Value = digitalRead(B0Pin);
  int b4Value = digitalRead(B1Pin);

 //b1 is set to represent 1 and b2 will represent 2 same with b3 and b4 pair
 //lets assume b1 = 1 b2 = 0 the number is 1
 //b3 is set to 1 and b4 is set to 1
 //input : b2|b1 + b4|b3
 //         0| 1    1| 1
 //sum = 1*1 + 0*2 + 1*1 + 1*2 = 4 - which is represented in binary as b100
  int sum = (b1Value * 1) + (b2Value * 2) + (b3Value * 1) + (b4Value * 2);

  if (sum & 0x1) //binary rep b001 - following the example will result in 0
    digitalWrite(LED0Pin, HIGH);
  else
    digitalWrite(LED0Pin, LOW);

  if (sum & 0x2) //binary rep b010 - following the example will result in 0
    digitalWrite(LED1Pin, HIGH);
  else
    digitalWrite(LED1Pin, LOW);

  if (sum & 0x4) //binary rep b100 - following the example will result in 1
    digitalWrite(LED2Pin, HIGH);
  else
    digitalWrite(LED2Pin, LOW);

  delay(10);
}